***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 06, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5453E-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2   205u TC=3m
Rg     g1    g2     2.726
M1     d2     g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=145  VTO=-2.31  THETA=0  VMAX=1.2e5  ETA=0  LEVEL=3  GAMMA=1.04  nfs=8.9011e11)
Rd     d1    d2    8.09m TC=4.9m,5e-6
Dbd    d2    s2    Dbt
.MODEL     Dbt    D(BV=44  TBV1=6.405e-4 TBV2=-1.105e-6  M=5.130e-1  CJO=4.361e-10  VJ=2.585e-1 )
Dbody   21   s2    DBODY
.MODEL DBODY  D(IS=3.926e-13    N=0.91   RS=0.04u  EG=1.11  TT=30n ikf=8.77e-1)
Rdiode  d1  21    2.05e-3  TC=0.7m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.177e-09
.MODEL     DGD    D(M=3.955e-1  CJO=1.186e-09   VJ=3.003e-1)
Rpar      b    d2   1Meg
Dgd       d2    a   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    1.627e-09
.ENDS
*$
